sierradb/flake.nix at main · sierra-db/sierradb · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
{
  description = "Rust development environment";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    rust-overlay = {
      url = "github:oxalica/rust-overlay";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs =
    {
      nixpkgs,
      rust-overlay,
      ...
    }:
    let
      supportedSystems = [
        "x86_64-linux"
        "aarch64-linux"
        "x86_64-darwin"
        "aarch64-darwin"
      ];
      forAllSystems = function: nixpkgs.lib.genAttrs supportedSystems function;
    in
    {
      packages = forAllSystems (
        system:
        let
          pkgs = import nixpkgs {
            inherit system;
            overlays = [ rust-overlay.overlays.default ];
          };
        in
        {
          default = pkgs.callPackage ./default.nix { };
        }
      );

      devShells = forAllSystems (
        system:
        let
          pkgs = import nixpkgs {
            inherit system;
            overlays = [ rust-overlay.overlays.default ];
          };

          commonInputs = with pkgs; [
            bacon
            cargo-expand
            cargo-generate
            cargo-msrv
            cargo-outdated
            cargo-semver-checks
            cargo-temp
            redis
            pkg-config
            openssl.dev
          ];

          hook = ''
            ulimit -n 4096
          '';
        in
        {
          default = pkgs.mkShell {
            name = "rust-dev";
            buildInputs =
              commonInputs
              ++ (with pkgs; [
                (rust-bin.stable.latest.default.override {
                  extensions = [
                    "rust-src"
                    "rustfmt"
                    "rust-analyzer"
                  ];
                })
              ]);
            shellHook = hook;
          };

          fuzz = pkgs.mkShell {
            name = "rust-fuzz-dev";
            buildInputs =
              commonInputs
              ++ (with pkgs; [
                (rust-bin.nightly.latest.default.override {
                  extensions = [
                    "rust-src"
                    "rustfmt"
                    "rust-analyzer"
                  ];
                })
                cargo-fuzz
              ]);
            shellHook = hook;
          };
        }
      );
    };
}