Skip to content

sql-statement-create-table.md

Latest commit

 

History

History
306 lines (235 loc) · 14.8 KB

sql-statement-create-table.md

File metadata and controls

306 lines (235 loc) · 14.8 KB
Raw
title CREATE TABLE | TiDB SQL Statement Reference
summary TiDBデータベースにおけるCREATE TABLEの使用方法の概要。

テーブルを作成する {#create-table}

このステートメントは、現在選択されているデータベースに新しいテーブルを作成します。MySQL のCREATE TABLEステートメントと同様の動作をします。

あらすじ {#synopsis}

CreateTableStmt ::=
    'CREATE' OptTemporary 'TABLE' IfNotExists TableName ( TableElementListOpt CreateTableOptionListOpt PartitionOpt DuplicateOpt AsOpt CreateTableSelectOpt | LikeTableWithOrWithoutParen ) OnCommitOpt

OptTemporary ::=
    ( 'TEMPORARY' | ('GLOBAL' 'TEMPORARY') )?

IfNotExists ::=
    ('IF' 'NOT' 'EXISTS')?

TableName ::=
    Identifier ('.' Identifier)?

TableElementListOpt ::=
    ( '(' TableElementList ')' )?

TableElementList ::=
    TableElement ( ',' TableElement )*

TableElement ::=
    ColumnDef
|   Constraint

ColumnDef ::=
    ColumnName ( Type | 'SERIAL' ) ColumnOptionListOpt

ColumnOptionListOpt ::=
    ColumnOption*

ColumnOptionList ::=
    ColumnOption*

ColumnOption ::=
    'NOT'? 'NULL'
|   'AUTO_INCREMENT'
|   PrimaryOpt 'KEY' ( 'GLOBAL' | 'LOCAL' )?
|   'UNIQUE' 'KEY'? ( 'GLOBAL' | 'LOCAL' )?
|   'DEFAULT' DefaultValueExpr
|   'SERIAL' 'DEFAULT' 'VALUE'
|   'ON' 'UPDATE' NowSymOptionFraction
|   'COMMENT' stringLit
|   ConstraintKeywordOpt 'CHECK' '(' Expression ')' EnforcedOrNotOrNotNullOpt
|   GeneratedAlways 'AS' '(' Expression ')' VirtualOrStored
|   ReferDef
|   'COLLATE' CollationName
|   'COLUMN_FORMAT' ColumnFormat
|   'STORAGE' StorageMedia
|   'AUTO_RANDOM' OptFieldLen

Constraint ::=
    IndexDef
|   ForeignKeyDef

IndexDef ::=
    ( 'INDEX' | 'KEY' ) IndexName? '(' KeyPartList ')' IndexOption?

KeyPartList ::=
    KeyPart ( ',' KeyPart )*

KeyPart ::=
    ColumnName ( '(' Length ')')? ( 'ASC' | 'DESC' )?
|   '(' Expression ')' ( 'ASC' | 'DESC' )?

IndexOption ::=
    'COMMENT' String
|   ( 'VISIBLE' | 'INVISIBLE' )
|   ('USING' | 'TYPE') ('BTREE' | 'RTREE' | 'HASH')
|   ( 'GLOBAL' | 'LOCAL' )

ForeignKeyDef
         ::= ( 'CONSTRAINT' Identifier )? 'FOREIGN' 'KEY'
             Identifier? '(' ColumnName ( ',' ColumnName )* ')'
             'REFERENCES' TableName '(' ColumnName ( ',' ColumnName )* ')'
             ( 'ON' 'DELETE' ReferenceOption )?
             ( 'ON' 'UPDATE' ReferenceOption )?

ReferenceOption
         ::= 'RESTRICT'
           | 'CASCADE'
           | 'SET' 'NULL'
           | 'SET' 'DEFAULT'
           | 'NO' 'ACTION'

CreateTableOptionListOpt ::=
    TableOptionList?

PartitionOpt ::=
    ( 'PARTITION' 'BY' PartitionMethod PartitionNumOpt SubPartitionOpt PartitionDefinitionListOpt )?

DuplicateOpt ::=
    ( 'IGNORE' | 'REPLACE' )?

TableOptionList ::=
    TableOption ( ','? TableOption )*

TableOption ::=
    PartDefOption
|   DefaultKwdOpt ( CharsetKw EqOpt CharsetName | 'COLLATE' EqOpt CollationName )
|   ( 'AUTO_INCREMENT' | 'AUTO_ID_CACHE' | 'AUTO_RANDOM_BASE' | 'AVG_ROW_LENGTH' | 'CHECKSUM' | 'TABLE_CHECKSUM' | 'KEY_BLOCK_SIZE' | 'DELAY_KEY_WRITE' | 'SHARD_ROW_ID_BITS' | 'PRE_SPLIT_REGIONS' ) EqOpt LengthNum
|   ( 'CONNECTION' | 'PASSWORD' | 'COMPRESSION' ) EqOpt stringLit
|   RowFormat
|   ( 'STATS_PERSISTENT' | 'PACK_KEYS' ) EqOpt StatsPersistentVal
|   ( 'STATS_AUTO_RECALC' | 'STATS_SAMPLE_PAGES' ) EqOpt ( LengthNum | 'DEFAULT' )
|   'STORAGE' ( 'MEMORY' | 'DISK' )
|   'SECONDARY_ENGINE' EqOpt ( 'NULL' | StringName )
|   'UNION' EqOpt '(' TableNameListOpt ')'
|   'ENCRYPTION' EqOpt EncryptionOpt
|    'TTL' EqOpt TimeColumnName '+' 'INTERVAL' Expression TimeUnit (TTLEnable EqOpt ( 'ON' | 'OFF' ))? (TTLJobInterval EqOpt stringLit)?
|   'AFFINITY' EqOpt StringName
|   PlacementPolicyOption

OnCommitOpt ::=
    ('ON' 'COMMIT' 'DELETE' 'ROWS')?

PlacementPolicyOption ::=
    "PLACEMENT" "POLICY" EqOpt PolicyName
|   "PLACEMENT" "POLICY" (EqOpt | "SET") "DEFAULT"

DefaultValueExpr ::=
    NowSymOptionFractionParentheses
|   SignedLiteral
|   NextValueForSequenceParentheses
|   BuiltinFunction

BuiltinFunction ::=
    '(' BuiltinFunction ')'
|   identifier '(' ')'
|   identifier '(' ExpressionList ')'
|   "REPLACE" '(' ExpressionList ')'

NowSymOptionFractionParentheses ::=
    '(' NowSymOptionFractionParentheses ')'
|   NowSymOptionFraction

NowSymOptionFraction ::=
    NowSym
|   NowSymFunc '(' ')'
|   NowSymFunc '(' NUM ')'
|   CurdateSym '(' ')'
|   "CURRENT_DATE"

NextValueForSequenceParentheses ::=
    '(' NextValueForSequenceParentheses ')'
|   NextValueForSequence

NextValueForSequence ::=
    "NEXT" "VALUE" forKwd TableName
|   "NEXTVAL" '(' TableName ')'

以下のテーブルオプションがサポートされています。 AVG_ROW_LENGTH 、 CHECKSUM 、 COMPRESSION 、 CONNECTION 、 DELAY_KEY_WRITE 、 {{B ENGINE 、 KEY_BLOCK_SIZE 、 MAX_ROWS 、 MIN_ROWSおよびSTATS_PERSISTENT ROW_FORMATのその他のオプションは解析されますが無視されます。

オプション 説明 例
AUTO_INCREMENT 増分フィールドの初期値 AUTO_INCREMENT = 5
SHARD_ROW_ID_BITS 暗黙の_tidb_rowidシャードのビット数を設定するには SHARD_ROW_ID_BITS = 4
PRE_SPLIT_REGIONS テーブル作成時に2^(PRE_SPLIT_REGIONS)領域を事前に分割するには PRE_SPLIT_REGIONS = 4
AUTO_ID_CACHE TiDBインスタンスで自動IDキャッシュサイズを設定します。デフォルトでは、TiDBは自動IDの割り当て速度に応じてこのサイズを自動的に変更します。 AUTO_ID_CACHE = 200
AUTO_RANDOM_BASE auto_randomの初期増分値を設定します。このオプションは内部インターフェースの一部とみなすことができます。ユーザーはこのパラメータを無視できます。 AUTO_RANDOM_BASE = 0
CHARACTER SET テーブルの文字セットを指定するには CHARACTER SET = 'utf8mb4'
COLLATE テーブルの文字セット照合順序を指定するには COLLATE = 'utf8mb4_bin'
COMMENT コメント情報 COMMENT = 'コメント情報'
AFFINITY テーブルまたはパーティションのアフィニティスケジューリングを有効にするには、この設定を使用します。パーティション化されていないテーブルの場合は'table'に、パーティション化されたテーブルの場合は'partition'に設定できます。 'none'に設定するか、空欄のままにすると、アフィニティスケジューリングが無効になります。 AFFINITY = 'テーブル'

注記：

  • split-table設定オプションはデフォルトで有効になっています。このオプションを有効にすると、新しく作成されるテーブルごとに個別のリージョンが作成されます。詳細は、 TiDB設定ファイル参照してください。
  • AFFINITYを使用する前に、アフィニティが有効になっているテーブルのパーティショニング スキームの変更 (パーティションの追加、削除、再編成、または交換など) はサポートされておらず、一時テーブルまたはビューでAFFINITYを構成することもサポートされていないことに注意してください。

注記：

  • TiDBは、新しく作成されたテーブルごとに個別のリージョンを作成します。
  • AFFINITYを使用する前に、アフィニティが有効になっているテーブルのパーティショニング スキームの変更 (パーティションの追加、削除、再編成、または交換など) はサポートされておらず、一時テーブルまたはビューでAFFINITYを構成することもサポートされていないことに注意してください。

例 {#examples}

シンプルな表を作成し、1行を挿入する：

CREATE TABLE t1 (a int);
DESC t1;
SHOW CREATE TABLE t1\G
INSERT INTO t1 (a) VALUES (1);
SELECT * FROM t1;
mysql> drop table if exists t1;
Query OK, 0 rows affected (0.23 sec)

mysql> CREATE TABLE t1 (a int);
Query OK, 0 rows affected (0.09 sec)

mysql> DESC t1;
+-------+------+------+------+---------+-------+
| Field | Type | Null | Key  | Default | Extra |
+-------+------+------+------+---------+-------+
| a     | int  | YES  |      | NULL    |       |
+-------+------+------+------+---------+-------+
1 row in set (0.00 sec)

mysql> SHOW CREATE TABLE t1\G
*************************** 1. row ***************************
       Table: t1
Create Table: CREATE TABLE `t1` (
  `a` int DEFAULT NULL
) ENGINE=InnoDB DEFAULT CHARSET=utf8mb4 COLLATE=utf8mb4_bin
1 row in set (0.00 sec)

mysql> INSERT INTO t1 (a) VALUES (1);
Query OK, 1 row affected (0.03 sec)

mysql> SELECT * FROM t1;
+------+
| a    |
+------+
|    1 |
+------+
1 row in set (0.00 sec)

テーブルが存在する場合は削除し、存在しない場合は条件付きでテーブルを作成する。

DROP TABLE IF EXISTS t1;
CREATE TABLE IF NOT EXISTS t1 (
 id BIGINT NOT NULL PRIMARY KEY auto_increment,
 b VARCHAR(200) NOT NULL
);
DESC t1;
mysql> DROP TABLE IF EXISTS t1;
Query OK, 0 rows affected (0.22 sec)

mysql> CREATE TABLE IF NOT EXISTS t1 (
         id BIGINT NOT NULL PRIMARY KEY auto_increment,
         b VARCHAR(200) NOT NULL
        );
Query OK, 0 rows affected (0.08 sec)

mysql> DESC t1;
+-------+--------------+------+------+---------+----------------+
| Field | Type         | Null | Key  | Default | Extra          |
+-------+--------------+------+------+---------+----------------+
| id    | bigint       | NO   | PRI  | NULL    | auto_increment |
| b     | varchar(200) | NO   |      | NULL    |                |
+-------+--------------+------+------+---------+----------------+
2 rows in set (0.00 sec)

MySQLとの互換性 {#mysql-compatibility}

  • 空間型を除くすべてのデータ型がサポートされています。

  • TiDB は、MySQL との互換性のために、 HASH 、 BTREE 、 RTREEなどのインデックス タイプを構文で受け入れますが、それらを無視します。

  • TiDB Self-Managed およびTiDB Cloud DedicatedはFULLTEXT構文の解析をサポートしていますが、 FULLTEXTインデックスの使用はサポートしていません。

    注記：

    現在、特定の AWS リージョンのTiDB Cloud StarterとTiDB Cloud EssentialインスタンスのみがFULLTEXT構文と索引をサポートしています。

  • PRIMARY KEYインデックス オプションを使用して、 UNIQUE INDEXまたはGLOBALグローバル インデックスとしてグローバルインデックスことは、パーティション化パーティション化されたテーブルの TiDB 拡張機能であり、MySQL とは互換性がありません。

  • 互換性のために、 index_col_name属性は、デフォルトで最大長3072バイトの長さオプションをサポートしています。長さの制限はmax-index-length設定オプションで変更できます。詳細は、 TiDB設定ファイル参照してください。
  • 互換性のために、 index_col_name属性は、最大長制限3072バイトの長さオプションをサポートしています。
  • [ASC | DESC]内のindex_col_nameは現在解析されますが無視されます (MySQL 5.7互換の動作)。
  • COMMENT属性はWITH PARSERオプションをサポートしていません。
  • TiDBは、デフォルトでは1つのテーブルで1017列、最大4096列をサポートします。InnoDBにおける対応する列数の制限は1017列、MySQLにおけるハードリミットは4096列です。詳細はTiDBの制限事項を参照してください。
  • TiDB はHASH 、 RANGE 、 LIST 、およびKEYサポートしていますパーティショニングの種類されていないパーティション タイプの場合、TiDB はWarning: Unsupported partition type %s, treat as normal tableを返します。ここで、 %sはサポートされていない特定のパーティション タイプです。

関連項目 {#see-also}