opm/src/cmd/Классы/КомандаOpm_Show.os at dc2e5a4ed4c91a9079e83b9880771c5c147cacd2 · oscript-library/opm · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
///////////////////////////////////////////////////////////////////////////////////////////////////
// Прикладной интерфейс

Процедура ОписаниеКоманды(Знач КомандаПриложения) Экспорт

	КомандаПриложения.Опция("l local", Ложь, "Искать в локально установленных пакетах");
	КомандаПриложения.Опция("r regex", Ложь, "Строка поиска будет использоваться как регулярное выражение");

	КомандаПриложения.Аргумент("PACKAGE", "", "Строка поиска пакета")
		.ТМассивСтрок()
		.Обязательный(Истина);

КонецПроцедуры

Процедура ВыполнитьКоманду(Знач КомандаПриложения) Экспорт

	УстановкаВЛокальныйКаталог = КомандаПриложения.ЗначениеОпции("local");
	ИспользоватьРегулярныеВыражения = КомандаПриложения.ЗначениеОпции("regex");
	МассивПоисковыхЗапросов = КомандаПриложения.ЗначениеАргумента("PACKAGE");

	ШаблоныПоиска = Новый Массив;

	Для Каждого мТекстЗапроса Из МассивПоисковыхЗапросов Цикл

		Если ИспользоватьРегулярныеВыражения Тогда

			РегулярноеВыражение = Новый РегулярноеВыражение(мТекстЗапроса);
			РегулярноеВыражение.ИгнорироватьРегистр = Истина;

			ШаблоныПоиска.Добавить(РегулярноеВыражение);

		Иначе
			ШаблоныПоиска.Добавить(ВРЕГ(СокрЛП(мТекстЗапроса)));
		КонецЕсли;

	КонецЦикла;

	Если УстановкаВЛокальныйКаталог Тогда
		ПутьККаталогуПакетов = ОбъединитьПути(ТекущийКаталог(), КонстантыOpm.ЛокальныйКаталогУстановкиПакетов);
		КэшУстановленныхПакетов = Новый КэшУстановленныхПакетов(ПутьККаталогуПакетов);
	Иначе
		КэшУстановленныхПакетов = КэшУстановленныхПакетовГлобальныхПакетов();
	КонецЕсли;

	УстановленныеПакеты = КэшУстановленныхПакетов.ПолучитьУстановленныеПакеты();

	КоличествоНайденныхПакетов = 0;
	Для Каждого УстановленныйПакет Из УстановленныеПакеты Цикл
		ИмяПакета = УстановленныйПакет.Ключ;
		Для Каждого мШаблонПоиска Из ШаблоныПоиска Цикл

			Если Совпадает(мШаблонПоиска, ИмяПакета) Тогда
				КоличествоНайденныхПакетов = КоличествоНайденныхПакетов + 1;
				ВывестиИнформациюОПакете(УстановленныйПакет.Значение);
				Прервать;
			КонецЕсли;

		КонецЦикла;

	КонецЦикла;

	Сообщить(СтрШаблон("Найдено пакетов: %1", КоличествоНайденныхПакетов));

КонецПроцедуры

Функция Совпадает(Знач ОбъектСравнения, Знач СтрокаПоиска)

	Если ТипЗнч(ОбъектСравнения) = Тип("РегулярноеВыражение") Тогда
		Возврат ОбъектСравнения.Совпадает(СтрокаПоиска);
	Иначе
		Возврат ВРЕГ(СокрЛП(СтрокаПоиска)) = ОбъектСравнения;
	КонецЕсли;

КонецФункции

Процедура ВывестиИнформациюОПакете(Знач УстановленныйПакет)

	Сообщить(СтрШаблон("Каталог: %1", УстановленныйПакет.КаталогПакета));
	Если УстановленныйПакет.Свойство("Перекрывает") Тогда

		Для Каждого мПакет Из УстановленныйПакет.Перекрывает Цикл
			Сообщить(СтрШаблон("	! Перекрывает: %1", мПакет.КаталогПакета));
		КонецЦикла;

	КонецЕсли;

	ОписаниеПакета = УстановленныйПакет.МетаданныеПакета;
	Если ТипЗнч(ОписаниеПакета) <> Тип("Булево") Тогда


		Свойства = ОписаниеПакета.Свойства();
		Для Каждого мСвойство Из Свойства Цикл
			Сообщить(СтрШаблон("	%1: %2", мСвойство.Ключ, мСвойство.Значение));
		КонецЦикла;

		Зависимости = ОписаниеПакета.Зависимости();
		Зависимости.Сортировать("ДляРазработки");
		Для Каждого мЗависимость Из Зависимости Цикл

			Префикс = ?(мЗависимость.ДляРазработки, "Разработка зависит от", "Зависит от");
			СтрокаВерсииЗависимости = СтрокаВерсииЗависимости(мЗависимость);

			Сообщить(СтрШаблон("		%1 %2%3", Префикс, мЗависимость.ИмяПакета, СтрокаВерсииЗависимости));

		КонецЦикла;

	КонецЕсли;

КонецПроцедуры

Функция СтрокаВерсииЗависимости(Знач мЗависимость)

	Подстроки = Новый Массив;

	Если ЗначениеЗаполнено(мЗависимость.МинимальнаяВерсия) Тогда
		Подстроки.Добавить(">=" + мЗависимость.МинимальнаяВерсия);
	КонецЕсли;

	Если ЗначениеЗаполнено(мЗависимость.МаксимальнаяВерсия) Тогда
		Подстроки.Добавить("<=" + мЗависимость.МаксимальнаяВерсия);
	КонецЕсли;

	Если ЗначениеЗаполнено(Подстроки) Тогда
		Возврат " (" + СтрСоединить(Подстроки, ", ") + ")";
	КонецЕсли;

	Возврат "";

КонецФункции

Функция КэшУстановленныхПакетовГлобальныхПакетов()

	ПутьККаталогуПакетов = ПолучитьЗначениеСистемнойНастройки("lib.system");
	КэшУстановленныхПакетов = Новый КэшУстановленныхПакетов(ПутьККаталогуПакетов);

	ДополнительныеКаталоги = ПолучитьЗначениеСистемнойНастройки("lib.additional");
	Если ЗначениеЗаполнено(ДополнительныеКаталоги) Тогда

		Для Каждого мКаталогПоиска Из СтрРазделить(ДополнительныеКаталоги, ";") Цикл
			КэшУстановленныхПакетов.ДобавитьКаталогБиблиотек(СокрЛП(мКаталогПоиска));
		КонецЦикла;

	КонецЕсли;

	Возврат КэшУстановленныхПакетов;

КонецФункции