Filtering

[yajo]

The Problem

I want to keep some docnf settings dynamic, so I can change them freely with direct OS usage.

For example, some apps store the last window position. Dumping that into a home-manager configuration makes no sense.

I still want other settings stored into home-manager.

The Solution

I'd love to have some filters in dream2nix that allow me to include only certain paths, or exclude certain others. Some examples:

dconf dump / | dconf2nix --include /org/gnome/clocks --exclude /org/gnome/clocks/state

Alternatives

https://gitlab.com/yajoman/minfra/-/commit/415fd867176cdc9a9353538212567918ff9deb35

Additional context

No response

Happens in the latest version

• Yes, this feature is still missing.

[jtojnar]

Not sure we want to add more features that are not directly related to conversion. This feels like something an external tool could easily handle. On the other hand, this is something that could be common use case so making it convenient would be good.

Not exactly the same but someone used crudini:

dconf dump / | crudini --del - org/gnome/clocks/state/window

initool works for removal too:

dconf dump / | initool delete - org/gnome/clocks/state/window

Neither of the tools is very ergonomic, though.

[jtojnar]

I will accept pull requests for this but will not implement it myself.

[frantisekhanzlikbl]

I've ran into this, too, and found neither crudini nor initool very satisfactory. in case anyone else finds it helpful, here's a nushell script that parses the dconf dump, applies some filters (just stuff I needed myself thus far), and formats it again for processing by dconf2nix (with an optional alejandra call at the end to format the output):

#!/usr/bin/env nu

def parse_dump [] {
	lines
	| split list --split before --regex '^\[.*\]$' # split into multiple lists, each containing all lines of a single section, including the header.
	| skip 1 # we assume there's no global section.
	| each { |group| {
		name:     ($group | first | parse '[{name}]' | get 0.name), # unwrap the section name.
		contents: ($group | skip 1 | parse '{key}={value}' | transpose --header-row --as-record) # parse the individual KV pairs.
	} }
	| transpose --header-row --as-record # construct a single record with section names as keys.
}

def format_dump [] {
	($in
		| transpose name contents
		| where contents != {} # filter out empty sections, as dconf2nix chokes on these.
		| update contents { transpose key value | format pattern "{key}={value}" | str join "\n" }
		| format pattern "[{name}]\n{contents}" | str join "\n\n"
	) + "\n" # dconf2nix requires a trailing newline.
}

dconf dump /
	| parse_dump
	# filter out state & automatically inferred stuff.
	| (reject
		'org/gnome/desktop/a11y/applications'
		'org/gnome/desktop/interface'
		'org/gnome/desktop/sound'
		'org/gnome/desktop/wm/preferences'
		'org/gtk/settings/file-chooser'
	)
	| upsert 'com/github/wwmm/easyeffects/streamoutputs' { default {} | reject --ignore-errors 'output-device' }
	| upsert 'com/github/wwmm/easyeffects/streaminputs'  { default {} | reject --ignore-errors 'input-device' }
	| format_dump
	| dconf2nix
	| alejandra