java-sense-hat/build.gradle at master · larsgrefer/java-sense-hat · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
buildscript {
    repositories {
        maven {
            url "https://plugins.gradle.org/m2/"
        }
    }
    dependencies {
        classpath "io.codearte.gradle.nexus:gradle-nexus-staging-plugin:0.30.0"
        classpath "de.marcphilipp.gradle:nexus-publish-plugin:0.4.0"
    }
}

plugins {
    id "io.freefair.git-version"
    id "io.freefair.github.base"
}

allprojects {
    repositories {
        mavenCentral()
    }

    group = "de.larsgrefer.sense-hat"
}

github {
    slug = "larsgrefer/java-sense-hat"
    username = findProperty('githubUsername')
    token = findProperty('githubToken')
}

allprojects {

    plugins.withId("java") {
        java {
            toolchain {
                languageVersion = JavaLanguageVersion.of(8)
            }
        }
    }

    plugins.withId("maven-publish") {
        project.apply plugin: 'de.marcphilipp.nexus-publish'

        nexusPublishing {
            repositories {
                sonatype()
            }
        }

        project.apply plugin: "signing"
        project.apply plugin: "io.freefair.maven-central.validate-poms"

        signing {
            required { !version.endsWith('SNAPSHOT') && gradle.taskGraph.hasTask("publish") }
        }

        publishing {
            publications.withType(MavenPublication) {
                pom {
                    description = provider { project.description }
                    developers {
                        developer {
                            id = 'larsgrefer'
                            name = 'Lars Grefer'
                            email = 'github@larsgrefer.de'
                            timezone = 'Europe/Berlin'
                        }
                    }
                }
            }
        }
    }
}

apply plugin: "io.codearte.nexus-staging"

nexusStaging {
    stagingProfileId = '9d2198adfd84d'
    username = findProperty('ossrhUser')
    password = findProperty('ossrhPass')
    delayBetweenRetriesInMillis = 5000
}