Don't override a package if all versions are deprecated

Consider

  active-repositories:
    , repo-a
    , repo-b:override

and a package mypkg of which all versions in repo-b are deprecated (i.e. none is
preferred).

Before this patch, the solver would ignore all versions of mypkg in repo-a. After
this patch, it considers versions of mypkg in both repo-a and repo-b.

See #8502 for motivation

Author: amesgen

cabal-install-solver/src/Distribution/Solver/Types/PackageIndex.hs

@@ -22,6 +22,8 @@ module Distribution.Solver.Types.PackageIndex (
   -- * Updates
   merge,
   override,
+  OverrideOrMerge(..),
+  overrideOrMerge,
   insert,
   deletePackageName,
   deletePackageId,
@@ -181,6 +183,28 @@ override i1@(PackageIndex m1) i2@(PackageIndex m2) =
   expensiveAssert (invariant i1 && invariant i2) $
     mkPackageIndex (Map.unionWith (\_l r -> r) m1 m2)
 
+data OverrideOrMerge = Override | Merge
+  deriving (Eq, Show)
+
+-- | Combined override-or-merge of two indexes.
+--
+-- For any package, either 'override' or 'merge' the packages from the second
+-- index into the first based on the supplied predicate.
+--
+overrideOrMerge ::
+     Package pkg
+  => (PackageName -> OverrideOrMerge)
+  -> PackageIndex pkg
+  -> PackageIndex pkg
+  -> PackageIndex pkg
+overrideOrMerge strategy i1@(PackageIndex m1) i2@(PackageIndex m2) =
+  expensiveAssert (invariant i1 && invariant i2) $
+    mkPackageIndex (Map.unionWithKey overridePkg m1 m2)
+  where
+    overridePkg name l r = case strategy name of
+      Override -> r
+      Merge -> mergeBuckets l r
+
 -- | Inserts a single package into the index.
 --
 -- This is equivalent to (but slightly quicker than) using 'mappend' or

cabal-install/src/Distribution/Client/IndexUtils.hs

@@ -391,7 +391,21 @@ getSourcePackagesAtIndexState verbosity repoCtxt mb_idxState mb_activeRepos = do
         -> PackageIndex UnresolvedSourcePackage
       addIndex acc (RepoData _ _ _ _, CombineStrategySkip) = acc
       addIndex acc (RepoData _ _ idx _, CombineStrategyMerge) = PackageIndex.merge acc idx
-      addIndex acc (RepoData _ _ idx _, CombineStrategyOverride) = PackageIndex.override acc idx
+      addIndex acc (RepoData _ _ idx prefs, CombineStrategyOverride) =
+        PackageIndex.overrideOrMerge strategy acc idx
+        where
+          strategy pkgname
+            -- We only want to merge a package when no version in idx is marked
+            -- as preferred/when all versions are deprecated.
+            | Just pkgPrefs <- Map.lookup pkgname prefsByPkg
+            , null $ PackageIndex.lookupDependency idx pkgname pkgPrefs =
+                PackageIndex.Merge
+            | otherwise = PackageIndex.Override
+
+          prefsByPkg =
+            Map.fromListWith
+              intersectVersionRanges
+              [(name, range) | Dependency name range _ <- prefs]
 
   let pkgs :: PackageIndex UnresolvedSourcePackage
       pkgs = foldl' addIndex mempty pkgss'