Fix "always evaluate" for Logger anonymous function tuples (#15081)

Previously, when the configuration directive `always_evaluate_messages`
was set to true an exception was raised when a function that returns a
tuple was given to Logger:

  ```
  Logger.info(fn -> {"", []} end)
  ```

Would result in:

  ```
    ** (Protocol.UndefinedError) protocol String.Chars not implemented for Tuple

    Got value:

        {"", []}
  ```

Author: Odaeus

lib/logger/lib/logger.ex

@@ -1016,12 +1016,15 @@ defmodule Logger do
   end
 
   @doc false
-  def __evaluate_log__(data) when is_function(data, 0) do
-    data.()
+  def __evaluate_log__(data, metadata) when is_function(data, 0) do
+    case data.() do
+      {msg, new_metadata} -> {msg, Enum.into(new_metadata, metadata)}
+      data -> {data, metadata}
+    end
   end
 
-  def __evaluate_log__(data) do
-    data
+  def __evaluate_log__(data, metadata) do
+    {data, metadata}
   end
 
   @doc false
@@ -1151,8 +1154,7 @@ defmodule Logger do
 
       Application.get_env(:logger, :always_evaluate_messages, false) ->
         quote do
-          data = Logger.__evaluate_log__(unquote(data))
-          metadata = unquote(quoted_metadata)
+          {data, metadata} = Logger.__evaluate_log__(unquote(data), unquote(quoted_metadata))
 
           case Logger.__should_log__(unquote(level), __MODULE__) do
             nil -> :ok
@@ -1259,8 +1261,7 @@ defmodule Logger do
   defp no_log(data, metadata) do
     if Application.get_env(:logger, :always_evaluate_messages, false) do
       quote do
-        Logger.__evaluate_log__(unquote(data))
-        unquote(metadata)
+        Logger.__evaluate_log__(unquote(data), unquote(metadata))
         :ok
       end
     else

lib/logger/test/logger_test.exs

@@ -650,6 +650,7 @@ defmodule LoggerTest do
     Logger.configure(translator_inspect_opts: [])
   end
 
+  @tag formatter: [metadata: [:module, :meta]]
   test "always evaluate messages" do
     Logger.configure(
       always_evaluate_messages: true,
@@ -666,6 +667,16 @@ defmodule LoggerTest do
         Logger.info(send(self(), "runtime purged"))
       end
 
+      def runtime_purged_anonymous_function do
+        Logger.info(fn -> send(self(), "runtime purged anonymous function") end)
+      end
+
+      def runtime_purged_anonymous_tuple_function do
+        Logger.info(fn ->
+          {send(self(), "runtime purged anonymous tuple function"), meta: true}
+        end)
+      end
+
       def not_purged do
         Logger.error(send(self(), "not purged"))
       end
@@ -688,6 +699,24 @@ defmodule LoggerTest do
 
     assert_received "runtime purged"
 
+    assert capture_log(fn ->
+             Logger.configure(level: :debug)
+             AlwaysEvaluate.runtime_purged_anonymous_function()
+           end) =~ "runtime purged anonymous function"
+
+    assert_received "runtime purged anonymous function"
+
+    log =
+      capture_log(fn ->
+        Logger.configure(level: :debug)
+        AlwaysEvaluate.runtime_purged_anonymous_tuple_function()
+      end)
+
+    assert log =~ "module=LoggerTest.AlwaysEvaluate meta=true"
+    assert log =~ "runtime purged anonymous tuple function"
+
+    assert_received "runtime purged anonymous tuple function"
+
     assert capture_log(fn ->
              Logger.configure(level: :error)
              AlwaysEvaluate.compile_purged()