build: Fix format targets for envoy 1.37 LLVM toolchain change

Envoy 1.37 switched clang-format from a pip package to
@llvm_toolchain_llvm, which is not created when BAZEL_LLVM_PATH is set.
Use hermetic LLVM for format targets and add a fallback repo rule for
CI builds.

Signed-off-by: Tam Mach <tam.mach@cilium.io>

Author: sayboras

Makefile.dev

@@ -42,7 +42,7 @@ veryclean: force-non-root clean
 precheck: force-non-root
 	tools/check_repositories.sh
 
-FORMAT_EXCLUDED_PREFIXES = "./linux/" "./proxylib/" "./starter/"  "./vendor/" "./go/" "./envoy_build_config/"
+FORMAT_EXCLUDED_PREFIXES = "./linux/" "./proxylib/" "./starter/"  "./vendor/" "./go/" "./envoy_build_config/" "./work/" "./bin/"
 
 # The default set of sources assumes all relevant sources are dependecies of some tests!
 TIDY_SOURCES ?= $(shell bazel query 'kind("source file", deps(//tests/...))' 2>/dev/null | sed -n "s/\/\/cilium:/cilium\//p; s/\/\/tests:/tests\//p")
@@ -71,10 +71,10 @@ tidy-fix-head: compile_commands.json force-non-root
 	run-clang-tidy-18 -fix -format -style=file -quiet -extra-arg="-Wno-unknown-pragmas" -checks=misc-include-cleaner -j $(TIDY_JOBS) $(shell git diff-tree --no-commit-id --name-only -r --diff-filter=d HEAD) || echo "clang-tidy fix produced changes, please commit them."
 
 format: force-non-root
-	CARGO_BAZEL_REPIN=true $(BAZEL) $(BAZEL_OPTS) run $(BAZEL_BUILD_OPTS) @envoy//tools/code_format:check_format -- --path "$(PWD)" --skip_envoy_build_rule_check --add-excluded-prefixes $(FORMAT_EXCLUDED_PREFIXES) --bazel_tools_check_excluded_paths="./" --build_fixer_check_excluded_paths="./" check || echo "Format check failed, run 'make format-fix' locally to fix formatting errors."
+	CARGO_BAZEL_REPIN=true $(BAZEL) $(BAZEL_OPTS) run --repo_env=BAZEL_LLVM_PATH= @envoy//tools/code_format:check_format -- --path "$(PWD)" --skip_envoy_build_rule_check --add-excluded-prefixes $(FORMAT_EXCLUDED_PREFIXES) --bazel_tools_check_excluded_paths="./" --build_fixer_check_excluded_paths="./" check || echo "Format check failed, run 'make format-fix' locally to fix formatting errors."
 
 format-fix: force-non-root
-	CARGO_BAZEL_REPIN=true $(BAZEL) $(BAZEL_OPTS) run $(BAZEL_BUILD_OPTS) @envoy//tools/code_format:check_format -- --path "$(PWD)" --skip_envoy_build_rule_check --add-excluded-prefixes $(FORMAT_EXCLUDED_PREFIXES) --bazel_tools_check_excluded_paths="." --build_fixer_check_excluded_paths="./" fix
+	CARGO_BAZEL_REPIN=true $(BAZEL) $(BAZEL_OPTS) run --repo_env=BAZEL_LLVM_PATH= @envoy//tools/code_format:check_format -- --path "$(PWD)" --skip_envoy_build_rule_check --add-excluded-prefixes $(FORMAT_EXCLUDED_PREFIXES) --bazel_tools_check_excluded_paths="." --build_fixer_check_excluded_paths="./" fix
 
 # Run tests without debug by default.
 tests:  $(COMPILER_DEP) force-non-root SOURCE_VERSION proxylib/libcilium.so install-bazelisk

WORKSPACE

@@ -135,6 +135,13 @@ load("@envoy//bazel:toolchains.bzl", "envoy_toolchains")
 
 envoy_toolchains()
 
+# When BAZEL_LLVM_PATH is set, envoy_toolchains() skips creating the
+# llvm_toolchain_llvm repo, but envoy's clang-format target still depends on it.
+# Provide it only if it wasn't already created.
+load("//bazel:local_llvm.bzl", "local_llvm_repo")
+
+local_llvm_repo(name = "llvm_toolchain_llvm")
+
 load("@envoy//bazel:dependency_imports_extra.bzl", "envoy_dependency_imports_extra")
 
 envoy_dependency_imports_extra()

bazel/local_llvm.bzl

@@ -0,0 +1,38 @@
+"""Repository rule to provide llvm_toolchain_llvm when using a local LLVM toolchain.
+
+When BAZEL_LLVM_PATH is set (local toolchain mode), the toolchains_llvm
+llvm_toolchain() macro skips creating the llvm_toolchain_llvm repository.
+Envoy's tools/clang-format target still depends on @llvm_toolchain_llvm//:clang-format,
+so we need to provide it.
+"""
+
+def _local_llvm_repo_impl(repository_ctx):
+    llvm_path = repository_ctx.os.environ.get("BAZEL_LLVM_PATH", "")
+    clang_format = None
+
+    if llvm_path:
+        candidate = repository_ctx.path(llvm_path + "/bin/clang-format")
+        if candidate.exists:
+            clang_format = candidate
+
+    if not clang_format:
+        clang_format = repository_ctx.which("clang-format")
+
+    if not clang_format:
+        fail("Could not find clang-format. Set BAZEL_LLVM_PATH or ensure clang-format is on PATH.")
+
+    repository_ctx.symlink(clang_format, "bin/clang-format")
+    repository_ctx.file("BUILD.bazel", """\
+package(default_visibility = ["//visibility:public"])
+
+filegroup(
+    name = "clang-format",
+    srcs = ["bin/clang-format"],
+)
+""")
+
+local_llvm_repo = repository_rule(
+    implementation = _local_llvm_repo_impl,
+    environ = ["BAZEL_LLVM_PATH", "PATH"],
+    local = True,
+)