c3c/git_hash.cmake at master · c3lang/c3c · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
set(GIT_HASH "unknown")

if(EXISTS "${CMAKE_CURRENT_LIST_DIR}/.git/HEAD")
    file(READ "${CMAKE_CURRENT_LIST_DIR}/.git/HEAD" HASH)
    string(STRIP "${HASH}" HASH)

    if(HASH MATCHES "^ref: (.*)")
        set(HEAD "${CMAKE_MATCH_1}")
        if(EXISTS "${CMAKE_CURRENT_LIST_DIR}/.git/${HEAD}")
            file(READ "${CMAKE_CURRENT_LIST_DIR}/.git/${HEAD}" HASH)
            string(STRIP "${HASH}" HASH)
        else()
            set(HASH "")
            if(EXISTS "${CMAKE_CURRENT_LIST_DIR}/.git/packed-refs")
                file(READ "${CMAKE_CURRENT_LIST_DIR}/.git/packed-refs" PACKED_REFS)
                if("\n${PACKED_REFS}" MATCHES "\n([0-9a-f]+) ${HEAD}(\n|$)")
                    set(HASH "${CMAKE_MATCH_1}")
                endif()
            endif()
        endif()
    endif()

    if(NOT "${HASH}" STREQUAL "")
        set(GIT_HASH "${HASH}")
    endif()
endif()

message("Git Hash: ${GIT_HASH}")

set(NEW_CONTENTS "#pragma once\n#define GIT_HASH \"${GIT_HASH}\"\n")
set(OUTPUT_FILE "${CMAKE_BINARY_DIR}/git_hash.h")

if(EXISTS "${OUTPUT_FILE}")
    file(READ "${OUTPUT_FILE}" OLD_CONTENTS)
    if(NOT "${NEW_CONTENTS}" STREQUAL "${OLD_CONTENTS}")
        file(WRITE "${OUTPUT_FILE}" "${NEW_CONTENTS}")
    endif()
else()
    file(WRITE "${OUTPUT_FILE}" "${NEW_CONTENTS}")
endif()