katana/settings.gradle.kts at develop · alvr/katana · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
@file:Suppress("UnstableApiUsage")

rootProject.name = "Katana"

dependencyResolutionManagement {
    repositories {
        mavenCentral()
        google()
        maven {
            url = uri("https://central.sonatype.com/repository/maven-snapshots/")
            mavenContent { snapshotsOnly() }
        }
    }
}

pluginManagement {
    includeBuild("build-logic")
    repositories {
        gradlePluginPortal()
        mavenCentral()
        google()
        maven {
            url = uri("https://central.sonatype.com/repository/maven-snapshots/")
            mavenContent { snapshotsOnly() }
        }
    }
}

plugins {
    id("com.gradle.develocity") version "4.5.0"
    id("org.gradle.toolchains.foojay-resolver-convention") version "1.0.0"
}

develocity {
    val isCI = !System.getenv("CI").isNullOrEmpty()

    buildScan {
        termsOfUseUrl = "https://gradle.com/terms-of-service"
        termsOfUseAgree = "yes"
        publishing.onlyIf { isCI }
    }
}

// Keep in sync with build-logic/settings.gradle.kts
buildCache { local { directory = rootDir.resolve(".gradle/build-cache") } }

include(":app-android", ":macrobenchmark", ":shared")

includes("common", "core", "features")

fun includes(vararg directories: String, maxDepth: Int = 2) {
    directories.forEach { topDir ->
        rootDir
            .resolve(topDir)
            .walkTopDown()
            .maxDepth(maxDepth)
            .filter { file -> file.isDirectory && file.resolve("build.gradle.kts").exists() }
            .forEach { module -> include(":${module.relativeTo(rootDir).path.replace(File.separatorChar, ':')}") }
    }
}

enableFeaturePreview("STABLE_CONFIGURATION_CACHE")

enableFeaturePreview("TYPESAFE_PROJECT_ACCESSORS")