build.gradle.kts

import com.google.protobuf.gradle.proto
import java.io.BufferedReader
import java.io.FileInputStream
import java.io.InputStreamReader

plugins {
    // Configures how dependencies are managed, aka versions used etc
    `dependency-conventions`
    // Configures the common java settings (version, jars, manifest, locking etc)
    `java-common-conventions`
    // Configures the integration tests that can be run
    `integration-test-conventions`
    // For generating the java classes from the proto files
    id("com.google.protobuf")
}

dependencies {
    implementation("org.slf4j:slf4j-api")
    implementation("com.google.protobuf:protobuf-java")
    implementation("com.fasterxml.jackson.core:jackson-databind")
    implementation("com.fasterxml.jackson.datatype:jackson-datatype-joda")
    implementation("io.netty:netty-all")
    implementation("org.erlang.otp:jinterface")
    implementation("commons-codec:commons-codec")

    // because of uses of javax.xml.bind.DatatypeConverter
    implementation("javax.xml.bind:jaxb-api")

    //Test dependencies
    testImplementation("org.mockito:mockito-core")
    testImplementation("org.powermock:powermock-api-mockito2")
    testImplementation("org.powermock:powermock-module-junit4")
    testImplementation("org.powermock:powermock-reflect")
    testImplementation("org.hamcrest:hamcrest-core")
    testImplementation("com.jayway.awaitility:awaitility")
}

/**
 * ---------------------------------------------
 *              Base Config
 * ---------------------------------------------
 */
group = "com.basho.riak"

base {
    // Sets the name of the jar
    archivesName.set("riak-client")
}

/**
 * ---------------------------------------------
 *              Protobuf Generation
 * ---------------------------------------------
 */
// Make then use the internal configuration for dependencies
configurations.getByName("compileProtoPath").extendsFrom(configurations.getByName("internal"))
configurations.getByName("testCompileProtoPath").extendsFrom(configurations.getByName("internal"))

sourceSets {
    main {
        proto {
            // Configure it to point at the shared .proto files for the git submodule
            srcDir("${rootProject.projectDir}/riak_pb/src/")
        }
    }
}

protobuf {
    protoc {
        artifact = "com.google.protobuf:protoc:3.+"
    }
}

java {
    toolchain.languageVersion.set(JavaLanguageVersion.of(21))
}

// Generate the RiakMessageCodes.java file from the riak_pb_messages.csv file
tasks.register("generateMessageCodes") {
    doLast {
        val inputFile = File("${rootProject.projectDir}/riak_pb/src/riak_pb_messages.csv")
        val outputFile = File("${rootProject.projectDir}/src/main/java/com/basho/riak/protobuf/RiakMessageCodes.java")

        val inputStream = FileInputStream(inputFile)
        val bufferedReader = BufferedReader(InputStreamReader(inputStream))
        val outputContent = StringBuilder()

        outputContent.append(
            """package com.basho.riak.protobuf;

/**
 * WARNING: AUTO-GENERATED CODE. DO NOT EDIT THIS FILE.
 */
public final class RiakMessageCodes {

"""
        )

        val prefix = "\tpublic static final byte MSG_"
        val cast = "(byte)"

        bufferedReader.lines()
            .filter { !it.isNullOrEmpty() }
            .forEach { line ->
                val csv = line.split(",")
                val constName = csv[1].replaceFirst("^Rpb".toRegex(), "")
                outputContent.append(prefix).append(constName).append(" = ");

                val code = Integer.valueOf(csv[0])
                if (code > 127) {
                    outputContent.append(cast)
                }
                outputContent.append(csv[0]).append(";\n")
            }

        outputContent.append("\n}")
        outputFile.writeText(outputContent.toString())

        logger.lifecycle("New file has been created: $outputFile")
    }
}