build.gradle

plugins {
	id 'java-library'
	id 'eclipse'
	id 'idea'
	id 'net.neoforged.gradle.userdev' version '7.0.+'
}

version = '1.1.3'
group = 'sbm-charcoalblock'

base {
	archivesName = 'SBM-CharcoalBlock-1.21.4'
}

java.toolchain.languageVersion = JavaLanguageVersion.of(21)

processResources {
	exclude ".cache"
}

sourceSets.main.resources {
	srcDir 'src/generated/resources' //include generated files
}

runs {
	configureEach {
		systemProperty 'forge.logging.console.level', 'debug'
		modSource project.sourceSets.main
	}

	client {
		workingDirectory project.file('run/client')
	}

	server {
		workingDirectory project.file('run/server')
		argument '-nogui'
	}

    clientData {
		workingDirectory project.file('run/data')
		arguments.addAll '--mod', 'sbmcharcoalblock', '--all', '--output', file('src/generated/resources/').getAbsolutePath()
	}
}

dependencies {
	implementation 'net.neoforged:neoforge:21.4.12-beta'
}

tasks.named('jar', Jar).configure {
	exclude('com/builtbroken/ccb/datagen/**') //exclude files from the built jar that are only used to generate the assets & data

    manifest {
        attributes(["Specification-Title": "SBM-CharcoalBlock",
                    "Specification-Vendor": "Built Broken Modding",
                    "Specification-Version": "1",
                    "Implementation-Title": "SBM-CharcoalBlock",
                    "Implementation-Version": "${version}",
                    "Implementation-Vendor": "Built Broken Modding"])
    }
}

tasks.withType(JavaCompile).configureEach {
    options.encoding = 'UTF-8'
	options.release = 21
}