stdext/CMakeLists.txt at main · Bekenn/stdext · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
cmake_minimum_required(VERSION 3.15 FATAL_ERROR)

set(STDEXT_STANDALONE_BUILD FALSE)
if(CMAKE_CURRENT_SOURCE_DIR STREQUAL CMAKE_SOURCE_DIR)
    set(STDEXT_STANDALONE_BUILD TRUE)
    set_property(GLOBAL PROPERTY USE_FOLDERS ON)
    project(stdext
        HOMEPAGE_URL https://github.com/Bekenn/stdext/
        LANGUAGES CXX)
    set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
    set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
    set(CMAKE_CXX_EXTENSIONS OFF)
    set(CMAKE_CXX_VISIBILITY_PRESET hidden)
    set(CMAKE_VISIBILITY_INLINES_HIDDEN ON)
    if(MSVC)
        add_compile_options(/MP /W4 /WX)
        add_compile_definitions(_UNICODE)
    else()
        add_compile_options(-Wall -Wextra -Werror)
    endif()
    if(WIN32)
        add_compile_definitions(UNICODE)
    endif()
endif()

add_library(stdext)
target_include_directories(stdext PUBLIC include)
target_compile_features(stdext PUBLIC cxx_std_17 c_std_11)
set_target_properties(stdext PROPERTIES CXX_EXTENSIONS OFF)

if(WIN32)
    target_compile_definitions(stdext PRIVATE UNICODE)
endif()

if(MSVC)
    target_compile_definitions(stdext
        PUBLIC _SCL_SECURE_NO_WARNINGS _CRT_SECURE_NO_WARNINGS
        PRIVATE _UNICODE
    )
    target_compile_options(stdext PUBLIC /Zc:preprocessor PRIVATE /permissive-)
    set(NATVIS msvc/stdext.natvis)
else()
    target_compile_options(stdext PRIVATE -Wno-switch)
    set(NATVIS "")
endif()

file(GLOB_RECURSE HEADERS CONFIGURE_DEPENDS include/*)
file(GLOB_RECURSE SOURCES CONFIGURE_DEPENDS src/*)
file(GLOB_RECURSE POSIX_SOURCES CONFIGURE_DEPENDS src/posix/*)
file(GLOB_RECURSE WINDOWS_SOURCES CONFIGURE_DEPENDS src/windows/*)

unset(SOURCES_DISABLED)
if(WIN32)
    list(APPEND SOURCES_DISABLED ${POSIX_SOURCES})
elseif(UNIX)
    list(APPEND SOURCES_DISABLED ${WINDOWS_SOURCES})
endif()

target_sources(stdext PRIVATE ${SOURCES} ${HEADERS} ${NATVIS})
source_group(TREE ${CMAKE_CURRENT_SOURCE_DIR} FILES ${SOURCES} ${HEADERS} ${NATVIS})
set_source_files_properties(${SOURCES_DISABLED} PROPERTIES LANGUAGE "")

if(STDEXT_STANDALONE_BUILD)
    enable_testing()
    add_subdirectory(test)
    set_property(DIRECTORY PROPERTY VS_STARTUP_PROJECT test-stdext)
endif()